Apprendre le TreeView en Visual Basic

1

Option Explicit

2

Dim cat As New ADOX.Catalog

Catalogue ADOX.

3

Dim rsNoeuds As ADODB.Recordset

Recordset.

4

Dim mnIndex As Integer

Contiendra l'index d'un nœud.

5

Dim moDragNode As Object

Un item pouvant être déplacé.

6

Dim boFlagEC As Boolean

Drapeau indiquant si une opération de drag and drop est en cours.

7

Dim objDragNode As Object

Contiendra la référence à un nœud en cours de déplacement.

8

Dim tblDrag(3, 3) As String

Tableau qui contiendra diverses informations sur un nœud déplacé.

1

Private Sub Form_Load()

Remplissage d'un treeview.

2

  Set moDragNode = Nothing

3

  cmdLast_Click

Appel à la procédure pour ajouter un nœud de même niveau que le nœud sélectionné.

4

  cmdLast_Click

Bis repetita. On veut le remplir cet arbre, non ? Et puis, cela nous permet d'étudier la méthode d'ajout et de voir le résultat.

5

  TreeView1.Nodes(1).Selected = True

On sélectionne le nœud d'index 1 qui devient donc le nœud en cours.

6

  cmdChild_Click

Appel à la procédure pour ajouter un nœud enfant au nœud en cours.

7

  cmdChild_Click

Bis repetita.

8

  TreeView1.Nodes(2).Selected = True

9

  cmdChild_Click

10

  TreeView1.Nodes(5).Selected = True

11

  cmdChild_Click

12

End Sub

1

Private Sub cmdLast_Click()

Ajoute un nœud de même niveau que le nœud en cours, ou en dernière position si aucun nœud n'est sélectionné.

2

  Dim skey As String

3

  skey = GetNextKey()

Appel à la fonction qui retournera la valeur de la clé pour le nouveau nœud.

4

  On Error GoTo myerr Gestion d'erreur.

5

  TreeView1.Nodes.Add TreeView1.SelectedItem.Index, tvwLast, skey, "Last " & skey, 1, 2

Si le treeview n'a aucun nœud sélectionné, cette ligne génère une erreur 91, valeur utilisée par la gestion d'erreur (étiquette myerr:) afin de déterminer l'action à mener. Pour une explication détaillée du code de cette ligne, voyez ci-après.

6

  Exit Sub

Sortie de la procédure s'il n'y a pas d'erreur.

7

myerr:

Étiquette pour la gestion d'erreur.

8

  TreeView1.Nodes.Add , tvwLast, skey, "Last " & skey, 1, 2

Ajoute un nœud racine en dernière position, aucun nœud n'étant sélectionné.

9

  Exit Sub

Fin de la gestion d'erreur.

10

End Sub

objet

Expression d'objet qui correspond à un objet figurant dans la rubrique « Application ».

TreeView1.Nodes

relative

Facultatif. Numéro d'index ou clé d'un objet Node existant. La relation entre le nouveau nœud et ce nœud existant figure dans l'argument suivant, relationship.

TreeView1.SelectedItem.Index
C'est ici l'index du nœud sélectionné.

relationship

Facultatif. Spécifie l'emplacement relatif de l'objet Node, comme indiqué dans la section Valeurs.

Ici, tvwLast
(voir explication ci-après). La valeur par défaut de cet argument est tvwNext.

key

Facultatif. Chaîne unique permettant de récupérer l'objet Node à l'aide de la méthode Item.

Ici la valeur renvoyée par la fonction GetNextKey (ligne 3).

text

Chaîne qui apparaît dans l'objet Node.

Ici "Last " & skey
ainsi on pourra lire directement dans l'arbre l'action ayant généré le nœud et la clé dudit nœud.

image

Facultatif. Index d'une image au sein d'un contrôle ImageList associé.

Rappelez-vous que nous avons en effet créé une liste d'images avec deux images(10). 'image d'index 1 (dossier fermé) sera associée aux nœuds non sélectionnés…

Selectedimage

Facultatif. Index d'une image dans un contrôle ImageList associé et qui est affichée lorsque l'objet Node est sélectionné.

… et l'image d'index 2 (dossier ouvert) au nœud sélectionné.

1

Private Sub cmdChild_Click()

Ajoute un nœud enfant du nœud en cours.

2

  Dim oNodex As Node

Déclaration d'une variable objet Node.

3

  Dim skey As String

Déclaration d'une variable string qui contiendra la valeur calculée de la clé pour le nouveau nœud.

4

  Dim iIndex As Integer

Déclaration d'une variable integer qui contiendra la valeur d'index de l'item sélectionné dans l'arbre.

5

  On Error GoTo myerr

Gestion d'erreur.

6

  iIndex = TreeView1.SelectedItem.Index

S'il n'y a pas de nœud sélectionné, la ligne de code génère une erreur 91 qui sera traitée par la gestion d'erreur (étiquette myerr:).

7

  skey = GetNextKey()

Appel de la fonction qui retournera la valeur calculée de la clé pour le nouveau nœud.

8

  Set oNodex = TreeView1.Nodes.Add(iIndex, tvwChild, skey, "Child " & skey, 1, 2)

9

  oNodex.EnsureVisible

Le nouveau nœud enfant est visible.

10

  Exit Sub

Fin de la procédure s'il n'y a pas d'erreur.

11

myerr:

Étiquette de la gestion d'erreur.

12

  MsgBox ("Vous devez sélectionner un nœud pour ajouter un nœud enfant" & vbCrLf & _
"Si le treeview est vide, cliquez sur le bouton de commande Add Last pour créer le premier nœud.")

Affiche un message informant l'utilisateur de la marche à suivre.

13

  Exit Sub

Fin de la gestion d'erreur.

14

End Sub

1

Private Function GetNextKey() As String

La fonction retourne une nouvelle valeur de clé pour chaque nœud ajouté au TreeView (jusqu'à 999 nœuds).
Chaque nœud nécessite une clé unique. Si vous permettez aux utilisateurs de supprimer un nœud, il n'est pas possible d'utiliser [nbre de nœuds + 1] pour calculer la valeur de la clé d'un nouveau nœud.

2

  Dim sNewKey As String

3

  Dim iHold As Integer

Déclaration d'une variable qui contiendra la valeur d'index du nouveau nœud.

4

  Dim i As Integer

5

  On Error GoTo myerr

Gestion d'erreur.

6

  iHold = Val(TreeView1.Nodes(1 ).Key)

La variable contient ainsi la valeur 1, donc l'index du premier nœud. Cette ligne de code génère l'erreur #35600 s'il n'y a aucun nœud dans le treeview et c'est donc le traitement d'erreur qui interviendra.

7

  i = TreeView1.Nodes.Count

La variable i reçoit le nombre de nœuds de la collection Nodes. On pourra ainsi y faire référence pour atteindre le dernier nœud de la collection selon son index.

8

  iHold = Val(TreeView1.Nodes(i).Key)

Nous avons ici la valeur de la clé du dernier nœud de la collection…

9

  iHold = iHold + 1

… et là la valeur de la clé du nœud en voie de création.

10

  sNewKey = CStr(iHold) & "_"

La variable est affectée de la concaténation de la conversion en string du contenu de iHold (fonction CStr) et du caractère de soulignement.

11

  GetNextKey = sNewKey

La fonction présente retourne la valeur ainsi calculée comme étant la valeur de la clé du nouveau nœud.

12

  Exit Function

OUF !!!

13

myerr:

Gestion d'erreur.

14

  GetNextKey = "1_"

Le Treeview étant vide, il est retourné la valeur "1_" pour la clé du premier nœud.

15

  Exit Function

16

End Function

Index

Clé

Count

Index

Clé

Count

1

1

1

1

1

1

2

2

2

3

3

2

3

3

3

1

Private Sub cmdFirst_Click()

Ajoute un nœud en tête du niveau du nœud en cours (paramètre tvwFirst).

2

  Dim skey As String

3

  Dim iIndex As Integer

4

  On Error GoTo myerr

Gestion d'erreur.

5

  iIndex = TreeView1.SelectedItem.Index

Affectation à la variable de la valeur de l'index de l'item sélectionné.
Cette ligne de code génère une erreur 91 si aucun nœud n'est sélectionné dans le treeview.

6

  skey = GetNextKey()

La fonction appelée retourne la valeur de la clé pour le nouveau nœud.

7

  TreeView1.Nodes.Add iIndex, tvwFirst, skey, "First " & skey, 1, 2

Nous retrouvons la même instruction Add dont seul le paramètre qui change est le paramètre relative qui prend ici la valeur tvwFirst (voir explications §I.C.2.cAJOUTER UN NŒUD DE MÊME NIVEAU HIÉRARCHIQUE).

8

  Exit Sub

9

myerr:

Traitement des erreurs.

10

  MsgBox ("You must select a Node to do an Add First" & vbCrLf _
& "If the TreeView is empty us Add Last to create the first node")

Affiche un message demandant à l'utilisateur de sélectionner un nœud. C'est le traitement de l'erreur 91 éventuellement générée ligne 5.

11

  Exit Sub

12

End Sub

1

Private Sub cmdNext_Click()

Ajoute un nœud après le nœud en cours, de même niveau.

2

  Dim skey As String

3

  Dim iIndex As Integer

4

  On Error GoTo myerr

Gestion d'erreur.

5

  iIndex = TreeView1.SelectedItem.Index

Affectation à la variable de la valeur de l'index de l'item sélectionné.
Cette ligne génère une erreur 91 si aucun nœud n'est sélectionné.

6

  skey = GetNextKey()

La fonction appelée retourne la valeur de la clé pour le nouveau nœud.

7

  TreeView1.Nodes.Add iIndex, tvwNext, skey, "Next " & skey, 1, 2

Même litanie que pour les procédures précédentes. Ici, l'argument relative est tvwNext (voir explications §I.C.2.cAJOUTER UN NŒUD DE MÊME NIVEAU HIÉRARCHIQUE).

8

  Exit Sub

9

myerr:

Étiquette gestion d'erreur.

10

  MsgBox ("You must select a Node to do an Add Next" & vbCrLf _
& "If the TreeView is empty us Add Last to create the first node")

Affiche un message demandant à l'utilisateur de sélectionner un nœud.

11

  Exit Sub

12

End Sub

1

Private Sub cmdPrevious_Click()

Ajoute un nœud avant le nœud sélectionné, au même niveau.

2

  Dim skey As String

3

  Dim iIndex As Integer

4

  On Error GoTo myerr

5

  iIndex = TreeView1.SelectedItem.Index

Affectation à la variable de la valeur de l'index de l'item sélectionné.
Cette ligne de code génère une erreur 91 si aucun nœud n'est sélectionné.

6

  skey = GetNextKey()

La fonction renvoie la valeur de la clé du nouveau nœud.

7

  TreeView1.Nodes.Add iIndex, tvwPrevious, skey, "Previous " & skey, 1, 2

Cette fois, c'esttvwPrevious… (voir explications §I.C.2.cAJOUTER UN NŒUD DE MÊME NIVEAU HIÉRARCHIQUE).

8

  Exit Sub

9

myerr:

Gestion d'erreur.

10

  MsgBox ("Vous devez sélectionner un nœud pour pouvoir en ajouter un avant." & vbCrLf _
& "Si le TreeView est vide utilisez Add Last pour créer le premier nœud.")

Affiche un message demandant à l'utilisateur de sélectionner un nœud.

11

  Exit Sub

12

End Sub

1

Private Sub cmdRemove_Click()

Suppression du nœud sélectionné et de ses enfants le cas échéant.

2

  Dim iIndex As Integer

3

  On Error GoTo myerr

4

  iIndex = TreeView1.SelectedItem.Index

Affectation à la variable de la valeur de l'index de l'item sélectionné.
Cette ligne de code génère une erreur 91 si aucun nœud n'est sélectionné.

5

  TreeView1.Nodes.Remove iIndex

Supprime le nœud en cours.

6

  Exit Sub

7

myerr:

Gestion d'erreur.

8

  MsgBox ("Vous devez sélectionner un nœud pour le supprimer.")

Message pour avertir l'utilisateur…

9

  Exit Sub

10

End Sub

1

Sub WriteToTable(strBaseName As String, strTabName As String)

La procédure reçoit en argument le nom de la base et le nom de la table.

2

  Set rsNoeuds = New ADODB.Recordset

Déclaration d'un l'objet recordset.

3

  Dim i As Integer

4

  Dim iTmp As Integer

5

  Dim iIndex As Integer

6

  rsNoeuds.CursorLocation = adUseClient

On définit la propriété CursorLocation du recordset à « adUseClient ». Un curseur côté client autorise plus de fonctionnalités qu'un curseur externe. Essayez de mettre cette ligne en commentaire et lancez le programme, vous comprendrez tout de suite…

7

  rsNoeuds.Open cat.Tables(strTabName).Name, cat.ActiveConnection, _
adOpenDynamic, adLockOptimistic, adCmdTable

Création du recordset. On utilise encore ici le catalogue.
Cela permet de s'y habituer un petit peu.

8

  If rsNoeuds.RecordCount > 0 Then

Suppression des enregistrements pouvant être dans la table. Si on laissait des enregistrements précédents, le treeview ferait sans aucun doute un peu désordre pour le moins. Et si c'est le même arbre que l'on sauvegarde, on aurait des doublons, et Access n'aimerait pas.

9

    rsNoeuds.MoveFirst

Pour être sûr de démarrer la boucle qui suit au premier enregistrement.

10

    Do While rsNoeuds.EOF = False

Tant que la fin du recordset n'est pas atteinte…

11

      rsNoeuds.Delete

on supprime l'enregistrement en cours…

12

      rsNoeuds.MoveNext

… et on passe au suivant.

13

    Loop

14

  End If

15

  mnIndex = TreeView1.Nodes(1 ).Root.Index

Index du premier nœud parent de l'arborescence.

16

  iIndex = TreeView1.Nodes(mnIndex).FirstSibling.Index

On détermine maintenant l'index du premier fils (FirstSibling.Index) du premier nœud de la première hiérarchie, et on sauvegarde sa valeur dans la variable iIndex. Le contenu de cette variable évoluera (ligne 39) pour prendre la valeur de l'index des nœuds enfants éventuels du nœud racine en cours.

17

  iTmp = iIndex

On affecte la valeur de iIndex à la variable iTmp. Ainsi, le contenu de la variable iTmp reflétera toujours la valeur de l'index du nœud racine. Il servira ligne 28 de référence afin de savoir s'il y a d'autres nœuds enfants pour le nœud racine en cours.

18

  rsNoeuds.AddNew

Création du nouvel enregistrement.

19

  rsNoeuds("ID_NoeudParent") = "0_"

C'est le nœud racine d'une branche. Il n'a donc pas de nœud parent, d'où son ID = 0_. Rappelez-vous que la collection nodes est une collection de base 1…

20

  rsNoeuds("ID_Noeud") = TreeView1.Nodes(iIndex).Key

On écrit dans la base les valeurs respectives des propriétés du nœud.

21

  rsNoeuds("Nom_Noeud") = TreeView1.Nodes(iIndex).Text

22

  rsNoeuds("Image") = TreeView1.Nodes(iIndex).Image

23

  rsNoeuds("Selected_Image") = TreeView1.Nodes(iIndex).SelectedImage

24

  rsNoeuds.Update

Enregistrement.

25

  If TreeView1.Nodes(iIndex).Children > 0 Then

Si le nœud indexé iIndex (le nœud en cours) possède des enfants (la propriété children donne le nombre de nœuds enfants), on appelle la procédure pour écrire et sauvegarder les valeurs de leur propriété dans la base.

26

    WriteChild iIndex

27

  End If

28

  While iIndex <> TreeView1.Nodes(iTmp).LastSibling.Index

Tant que l'index du premier nœud enfant (déterminé ligne 16) du nœud en cours est différent de l'index du dernier nœud enfant du même nœud en cours.
Tant que l'index iIndex est différent de l'index du dernier nœud enfant du nœud indexé itemp (oui, je sais, c'est duuurrrr, faut s'accrocher), on enregistrera les nœuds dans la boucle.

29

    rsNoeuds.AddNew

On crée un nouvel enregistrement pour le nœud enfant…

30

    rsNoeuds("ID_NoeudParent") = "0_"

… et on écrit la valeur des propriétés du nœud enfant dans la table…

31

    rsNoeuds("Nom_Noeud") = TreeView1.Nodes(iIndex).Next.Text

32

    rsNoeuds("ID_Noeud") = TreeView1.Nodes(iIndex).Next.Key

33

    rsNoeuds("Image") = TreeView1.Nodes(iIndex).Next.Image

34

    rsNoeuds("Selected_Image") = TreeView1.Nodes(iIndex).Next.SelectedImage

35

    rsNoeuds.Update …puis on enregistre.

36

    If TreeView1.Nodes(iIndex).Next. Children > 0 Then

Si le nœud suivant (next) celui en cours (iIndex) contient lui-même des nœuds enfants (children>0)…

37

      WriteChild TreeView1.Nodes(iIndex).Next.Index

… on appelle la procédure WriteChild pour traiter ce prochain nœud enfant…

38

    End If

39

    iIndex = TreeView1.Nodes(iIndex).Next.Index

On passe au nœud suivant, dont on sauvegarde l'index dans la variable iIndex. N'oublions pas que nous sommes dans une boucle (commençant ligne 28).

40

  Wend

41

End Sub

OUF…, mais il faut voir la procédure WriteChild avant que d'être vraiment soulagé.

1

Private Sub WriteChild(ByVal iNodeIndex As Integer)

Écriture des nœuds enfants dans la table. C'est une procédure récursive pour parcourir dans une boucle tous les nœuds enfants. Elle identifie l'index du nœud ayant les enfants.
La procédure reçoit l'index du nœud parent en cours.

2

  Dim i As Integer

3

  Dim iTempIndex As Integer

4

  iTempIndex = TreeView1.Nodes(iNodeIndex).Child.FirstSibling.Index

La variable reçoit l'index du premier nœud fils du nœud parent en cours. Il y a forcément un nœud enfant, car la procédure n'est appelée que dans ce cas (code 14 - Ligne 26).

5

  For i = 1 To TreeView1.Nodes(iNodeIndex).Children

On parcourt (dans une boucle) tous les nœuds enfants du nœud parent en cours.

6

    rsNoeuds.AddNew

Création d'un enregistrement concernant le nœud enfant dans le recordset.

7

    rsNoeuds("ID_NoeudParent") = TreeView1.Nodes(iTempIndex).Parent.Key

Le champ ID_NoeudParent reçoit la valeur de la clé du nœud parent.

8

    rsNoeuds("ID_Noeud") = TreeView1.Nodes(iTempIndex).Key

Le champ ID_Noeud reçoit la valeur de la clé du champ enfant en cours.

9

    rsNoeuds("Nom_Noeud") = TreeView1.Nodes(iTempIndex).Text

Le champ Nom_Noeud reçoit la valeur de la propriété Text du champ enfant en cours.

10

    rsNoeuds("Image") = TreeView1.Nodes(iTempIndex).Image

Le champ Image reçoit la valeur de l'index de l'image contenue dans la liste d'images correspondante à un nœud non sélectionné.

11

    rsNoeuds("Selected_Image") = TreeView1.Nodes(iTempIndex).SelectedImage

Le champ Selected_Image reçoit la valeur de l'index de l'image contenue dans la liste d'images correspondante à un nœud sélectionné.

12

    rsNoeuds.Update

Mise à jour du recordset.

13

    If TreeView1.Nodes(iTempIndex).Children > 0 Then

Si le nœud en cours possède des nœuds enfants, la procédure s'appelle elle-même (récursivité). Elle se transmet l'index du nœud du niveau en cours, celui obtenu ligne 4 de cette procédure. On n'est jamais si bien servi que par soi-même.

14

      WriteChild (iTempIndex)

15

    End If

16

    If i <> TreeView1.Nodes(iNodeIndex).Children Then

Si ce n'est pas le dernier nœud enfant du nœud en cours, on passe au nœud enfant suivant.

17

      iTempIndex = TreeView1.Nodes(iTempIndex).Next.Index

18

    End If

19

  Next i

20

End Sub